TD-e.com

Fluttering flag

A script-fu for The Gimp

Example

Image used with the script 'Fluttering flag' to generate a fluttering flag

Original flat flag
More flat flags

Fluttering flag

Description

"Fluttering flag" is a script-fu for the Gimp. It animates an ordinary flat image of a flag by blowing wind onto the flag. More precisely, it creates a choosen number of layers that can be saved as an animated gif image. It is recommended to generate 8 layers and to use original images with a width under 200 pixels. The script will work with larger images too, but the produced gif animation will be a very big file, especially unsuitable to be published on the web.

The original image should be an RGB (24 bit depth), an RGBA (32 bit depth), a GRAY, GRAYA, INDEXED or INDEXEDA. That means that *.png files, *.gif or *.jpg files are usable.

Input parameters

- A low ripple parameter gives a quite waveless flag, a high ripple parameter gives a very wavy flag.
- The wind parameter (wind strength) affects the amplitude of the movement.
- The form factor can be a random number or a specific number. Some form factors produce better animations than others. Fine vertical dark lines may be created with some form factors, avoid them. Recommended values among others: 5, 14, 134, 199. If you do find a specially good form factor, please let me know.
- The check box "irregular shape" is only to be used with flags that do not have a rectangular or square shape, like e.g. the flag of Nepal. That allows white areas that reach the edge of the image to be treated as transparent. Such treatment will not be adequate for "regular" flags like Canada, US, Mexico, France, UK, NL, Luxembourg, Italy, etc... which contain white fields reaching the edges. Thus do not check the box "irregular shape" with rectangular flags.

Saving as a gif file

When saving the produced layers as a *.gif file, you will get 2 dialog boxes. In the 1st dialog box select:
- Save as Animation
In the 2nd dialog box select:
- Loop forever
- Delay between frames = 20 ms.
- Frame disposal = one frame per layer

Comments

This script aims to be more parameterizable and more aware of details than similar ones. Scripts using simple minimal algorithms will produce an animated flag looking like a flying carpet, moving in every part of its area, thus seeming to slide up and down on the mast. This script takes care of this and assures that the flag stays still near the mast.
The parameterizable wind strength is also a feature that many similar scripts do not implement.
The form factor may please you or may annoy you. In the second case, just stick to the default value of 5 and forget this parameter.

The script has been tested with The Gimp version 2.2.9 on Linux SuSE, with The Gimp version 2.2.10 on Windoze and with The Gimp version 2.2.13 on Linux Ubuntu.

The script version 1.20 has been tested with The Gimp version 2.4.0 on Linux Ubuntu 7.10 Gutsy Gibbon.

Versions:

2006.08.15 : Version 1.00
2007.09.16 : Version 1.10
The mast thickness can be adjusted, the mast is now optional.
A smoothing of the hitch of the repetition of the images has been implemented.
2007.10.25 : Version 1.20. The current version is 1.20 and has been adapted to The Gimp 2.4. It is now under the menu "Filters" and not anymore under the menu "script-Fu".
2008.04.05 : Version 1.21. Using the script on indexed pictures without grey in their palette did not always produce correct results, bug corrected.

Download:

Click into the blue frame below where the script is listed.
Type Control-A to select the complete text of the script.
Type Control-C to copy the script to the clipboard.
Go to your text editor (gedit, Kate, Aedix, Notepad, etc) and type Control-V to paste the script.
Save it as a file named fluttering-flag.scm

Linux Ubuntu or other Gnome:   use the text editor gedit or bluefish

Linux Kubuntu or other KDE:   use the text editor Kate or Quanta

Mac OS X:   use the text editor Smultron

Windoze:   use the text editor Aedix (free), or Notepad (but beware of the file extension .txt which is unwanted, the script file must have the extension .scm and not .scm.txt)

Other text editors are ok too, but word processors are not. Do not use Word, OpenOffice or similar tools.

Installation:

Copy fluttering-flag.scm into one of the directories registered in the Gimp preferences under Folders/Scripts.

Linux Ubuntu and many others:
  /home/[username]/.gimp-2.n/scripts   or   /usr/share/gimp/2.0/scripts

Linux SuSE:
  /home/[username]/.gimp-2.n/scripts   or   /opt/gnome/share/gimp/2.0/scripts

Windoze:
  C:\.gimp-2.n\scripts   or   C:\program-files\gimp2.n\share\gimp\scripts

Then go to the menu Xtns and select Xtns / Script-Fu / Refresh Scripts. That's it.
The script can be called in the menu Script-Fu / Animators / Fluttering flag...
ATTENTION : The version 1.20 can be called in the menu Filters / Animation / Fluttering flag....

Tutorial

A Tutorial to use the script 'Fluttering flag' is available.

Script-fu fluttering-flag.scm for The Gimp

Notice: Undefined index: isbrowser in /home/photowp/domains/td-e.com/public_html/pbin/func/piphost.php on line 58

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
; SCRIPT-FU-FLUTTERING-FLAG animates a flat image of a flag by blowing wind on it
; Copyright (c) 2006-2007  Tharsice Demand <www.td-e.com>
; version 1.00  2006.08.15  english
; version 1.10  2007.09.16  replaced set! with define for future compatibility,
;                           mast now optional, mast thickness can be adjusted,
;                           smoothing the hitch of the repetition of the images
; version 1.20  2007.10.25, migration to Gimp 2.4
; version 1.21  2008.04.05  indexed pictures without grey in their palette did not produce correct results, bug corrected
;
;This program is free software; you can redistribute it and/or
;modify it under the terms of the GNU General Public License
;as published by the Free Software Foundation; either version 2
;of the License, or (at your option) any later version.
;
;This program is distributed in the hope that it will be useful,
;but WITHOUT ANY WARRANTY; without even the implied warranty of
;MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;GNU General Public License for more details.
;
;You should have received a copy of the GNU General Public License
;along with this program; if not, write to the Free Software
;Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.
;
;Copy of the license at http://td-e.com/site/gpl.php

(define (script-fu-fluttering-flag image flatflag layertotal ripple windstrength formf mthickness hitch skycolor mastcolorl mastcolorr formrand skytrans irregular)
  (let*
    (
      (old-fg (car (gimp-context-get-foreground)))
      (old-bg (car (gimp-context-get-background)))
      (owidth (car (gimp-image-width image)))
      (oheight (car (gimp-image-height image)))
      (borderx (/ owidth 10))
      (bordery borderx)
      (mastlef (* borderx (- 0.80 (/ (* 0.60 mthickness) 100))))
      (mastrig (* borderx (+ 0.80 (/ (* 0.60 mthickness) 100))))
      (width (+ owidth (* 2 borderx)))
      (height (+ oheight (* 2 bordery)))
      (snx (/ ripple 10)) ;5..150 default to 25 -> 0.5..15 defaults to 2.5
      (sny 0.1) ;~ 0.1
      (flutterx (/ owidth (- layertotal 1))) ;dependent on num of layers
      (fluttery (/ oheight (- layertotal 1)))
      (layerindex 0)
      (formseed (if (= formrand TRUE) (rand 4294967295) (* formf 10000000))) ;(2^32-1 = 4 294 967 295)
      (fgcolormax hitch)
      (fgcolormin 0)
      (fgcolorval 0)
      (fgcolorvalar '(0 0 0))
      (attenmax (+ 0.40 (/ (* hitch 0.59) 255)))
      (attenmin 0.40)
      (attenval 0.40)
      ;---factors for smoothing the repetition---
      ; y = ax^2 + bx + c
      ; a = 4 (max - min) / layerindex^2  ; b= 4 (min -max) / layerindex  ; c= max
      ;
      ; attenuation
      ; max = 0.95  ; min = 0.40  ; a = 2.20 / layertotal^2 ;  b = - 2.20 / layertotal ;  c = 0.95
      ;
      ; foreground color
      ; max = 160  ; min = 0  ; a = 640 / layertotal^2 ;  b = - 640 / layertotal ;  c = 160
      ;
      (attena (/ (* 4 (- attenmax attenmin)) (* layertotal layertotal)))
      (attenb (/ (* 4 (- attenmin attenmax)) layertotal))
      (attenc attenmax)
      (fgcolora (/ (* 4 (- fgcolormax fgcolormin)) (* layertotal layertotal)))
      (fgcolorb (/ (* 4 (- fgcolormin fgcolormax)) layertotal))
      (fgcolorc fgcolormax)
    )
    (srand (realtime))
    (gimp-image-undo-group-start image)

(gimp-context-set-background '(255 255 255))
    (define flatflagf (car (gimp-image-flatten image)))

;---if not an RGB, make one---
    (if (= (car (gimp-drawable-is-rgb flatflagf)) 0) (gimp-image-convert-rgb image))

;---draw 1 pixel border around the flag---
    (if (= irregular FALSE)
      (begin
        (define (gen-contour-array owidth oheight)
          (let*
            ((contourarray (cons-array 10 'double)))
            (aset contourarray 0 0)
            (aset contourarray 1 0)
            (aset contourarray 2 owidth)
            (aset contourarray 3 0)
            (aset contourarray 4 owidth)
            (aset contourarray 5 oheight)
            (aset contourarray 6 0)
            (aset contourarray 7 oheight )
            (aset contourarray 8 0)
            (aset contourarray 9 0)
            contourarray
          )
        )
        (gimp-context-set-foreground '(128 128 128))
        (gimp-context-set-brush "Circle (01)")
        (gimp-paintbrush-default flatflagf 10 (gen-contour-array owidth oheight))
      )
    )
    (gimp-context-set-foreground '(0 0 0))

;---add a 10% border---
    (gimp-image-resize image width height borderx bordery)
    (gimp-layer-resize-to-image-size flatflagf)

(if (= (car (gimp-selection-is-empty image)) 1) (gimp-selection-all image))
    (define flag-select (car (gimp-selection-save image)))
    (gimp-selection-none image)

;---make the added border transparent---
    (gimp-fuzzy-select flatflagf 1 1 10 0 FALSE FALSE 0.0 0)
    (gimp-layer-add-alpha flatflagf)
    (gimp-edit-clear flatflagf)
    (gimp-selection-none image)

;---draw the mast layer---
    (define mastlayer (car (gimp-layer-new image width height 1 "mast" 100 0)))
    (gimp-layer-add-alpha mastlayer)
    (gimp-drawable-fill mastlayer 3)
    (gimp-image-add-layer image mastlayer 0)

(gimp-context-set-foreground mastcolorl)
    (gimp-context-set-background mastcolorr)

(define (gen-mast-array borderx bordery width height mastlef mastrig)
      (let*
        ((mastarray (cons-array 10 'double)))
        (aset mastarray 0 mastlef)
        (aset mastarray 1 (* bordery 0.5))
        (aset mastarray 2 mastrig)
        (aset mastarray 3 (* bordery 0.5))
        (aset mastarray 4 mastrig)
        (aset mastarray 5 height)
        (aset mastarray 6 mastlef)
        (aset mastarray 7 height )
        (aset mastarray 8 mastlef)
        (aset mastarray 9 (* bordery 0.5))
        mastarray
      )
    )

(define mastsel (gen-mast-array borderx bordery width height mastlef mastrig))
    (gimp-free-select image
                      10
                      mastsel
                      CHANNEL-OP-REPLACE
                      0
                      0
                      0.0)
    (if (>= mthickness 10)
      (gimp-edit-blend
        mastlayer FG-BG-RGB-MODE NORMAL-MODE GRADIENT-LINEAR
        100 0 REPEAT-NONE FALSE FALSE
        0 0 FALSE
        mastlef (/ height 2) mastrig (/ height 2)
      )
    )
    (gimp-selection-none image)

;---draw the sky layer---
    (if (= skytrans TRUE)
      (begin
        (define skylayer (car (gimp-layer-new image width height 1 "sky" 0 0)))
        (gimp-layer-add-alpha skylayer)
      )
      (begin
        (define skylayer (car (gimp-layer-new image width height 1 "sky" 100 0)))
        (gimp-layer-add-alpha skylayer)
        (gimp-context-set-foreground skycolor)
        (gimp-drawable-fill skylayer 0)
      )
    )
    (gimp-image-add-layer image skylayer 0)

;---draw the flutter layer---
    (define flutterlayer (car (gimp-layer-new image width height 1 "flutter" 100 0)))
    (gimp-drawable-fill flutterlayer 3)
    (gimp-image-add-layer image flutterlayer 0)

(plug-in-solid-noise 1 image flutterlayer 1 0 formseed 1 snx sny)
    (plug-in-gauss 1 image flutterlayer 5 5 0)
    (plug-in-c-astretch 1 image flutterlayer)
    (gimp-selection-load flag-select)

(while (< layerindex layertotal)
      ;---stabilize flag at mast---
      (define fluttercopy (car (gimp-layer-copy flutterlayer 1)))
      (gimp-drawable-set-name fluttercopy "fluttercopy")
      (gimp-image-add-layer image fluttercopy -1)

(define stablemast (car (gimp-layer-new image width height 1 "stablemast" 100 0)))
      (gimp-image-add-layer image stablemast -1)
      (define stablemastmask (car (gimp-layer-create-mask stablemast 0)))
      (gimp-layer-add-mask stablemast stablemastmask)
      (gimp-context-set-foreground '(128 128 128))
      (gimp-drawable-fill stablemast 0)

;---smoothing the repetition---
      ; y = ax ^ 2 + bx + c
      (set! attenval   (+ (+ (* attena   (* layerindex layerindex)) (* attenb   layerindex)) attenc))
      (set! fgcolorval (+ (+ (* fgcolora (* layerindex layerindex)) (* fgcolorb layerindex)) fgcolorc))
      (set! fgcolorvalar (list fgcolorval fgcolorval fgcolorval))

(gimp-context-set-foreground fgcolorvalar)
      (gimp-context-set-background '(255 255 255))

(gimp-edit-blend
          stablemastmask FG-BG-RGB-MODE NORMAL-MODE GRADIENT-LINEAR
          100 0 REPEAT-NONE TRUE FALSE
          0 0 FALSE
          (* borderx 0.80) (/ height 2) (* width attenval) (/ height 2))
      (define fluttermodif (car (gimp-image-merge-down image stablemast 1)))
      (gimp-drawable-set-name fluttermodif "fluttermodif")

;---blow onto the flag---
      (define flagcopy (car (gimp-layer-copy flatflagf 1)))
      (gimp-image-add-layer image flagcopy -1)

(plug-in-bump-map 1 image flagcopy fluttermodif 135 45 10 0 0 0 0 1 0 2)
      (plug-in-displace 1 image flagcopy (/ (* owidth windstrength) 400) (/ (* oheight windstrength) 100) 1 1 fluttermodif fluttermodif 1)
      (gimp-image-remove-layer image fluttermodif)
      (gimp-drawable-offset flutterlayer 1 0 flutterx fluttery)

;---add the sky---
      (define skycopy (car (gimp-layer-copy skylayer 1)))
      (gimp-image-add-layer image skycopy -1)
      (gimp-image-lower-layer image skycopy)
      (gimp-image-merge-down image flagcopy 1)

;---add the mast---
      (define mastcopy (car (gimp-layer-copy mastlayer 1)))
      (gimp-image-add-layer image mastcopy -1)
      (gimp-image-merge-down image mastcopy 1)

(set! layerindex (+ layerindex 1))
    )

(gimp-image-remove-layer image mastlayer)
    (gimp-image-remove-layer image skylayer)
    (gimp-image-remove-layer image flutterlayer)
    (gimp-image-remove-layer image flatflagf)
    (gimp-context-set-foreground old-fg)
    (gimp-context-set-background old-bg)

(gimp-selection-none image)
    (gimp-image-remove-channel image flag-select)
    (gimp-image-convert-indexed image 0 0 255 0 0 "")
    (gimp-image-undo-group-end image)
    (gimp-displays-flush)
  )
)
(script-fu-register "script-fu-fluttering-flag"
                    "<Image>/Filters/Animation/Fluttering flag..."
                    "Creates an animated flag made of a choosen number of layers. 
When saving as a gif file, select 
- Save as Animation 
- Loop forever
- Delay between frames = 100 ms. 
- Frame disposal = one frame per layer 
A high ripple parameter = a very wavy flag. 
The wind parameter affects the amplitude of the movement. 
The form factor can be random or specific. 
Recommended form factors: 5, 14, 134, 199."
                    "Tharsice Demand <td-e.com>"
                    "Tharsice Demand"
                    "2007.10.25"
                    "RGB RGBA GRAY GRAYA INDEXED INDEXEDA"
                    SF-IMAGE      "Image" 0
                    SF-DRAWABLE   "Drawable" 0
                    SF-ADJUSTMENT "Number of layers"                   '(8 4 32 1 4 0 1)
                    SF-ADJUSTMENT "Ripple"                             '(30 5 150 1 5 0 1)
                    SF-ADJUSTMENT "Wind"                               '(5 1 9 1 2 0 1)
                    SF-ADJUSTMENT "Form factor"                        '(5 1 400 1 10 0 1)
                    SF-ADJUSTMENT "Thickness of the mast"              '(60 5 100 1 10 0 1)
                    SF-ADJUSTMENT "Reduction of repetition hitch"      '(1 1 255 1 10 0 1)
                    SF-COLOR      "Color of the sky"                   '(128 170 255)
                    SF-COLOR      "Left color of mast gradient"        '(255 240 176)
                    SF-COLOR      "Right color of mast gradient"       '(80 48 16)
                    SF-TOGGLE     "Ignore form factor and make it random"            FALSE
                    SF-TOGGLE     "Ignore sky color and make background transparent" FALSE
                    SF-TOGGLE     "Flag shape is irregular non rectangular"          FALSE
)

Sponsorship

If you find the script 'Fluttering flag' useful and want to support the developer, you can

License

The GNU general public license applies to the script-fu fluttering-flag.scm above.

Blog of TD-e.com
Add a comment

... ...
.. ..
. .